ona/src/main.zig

const coral = @import("coral");

const std = @import("std");

const ona = @import("ona");

const ChromaticAberration = extern struct {
	magnitude: f32,
};

const Actors = struct {
	instances: coral.stack.Sequential(@Vector(2, f32)) = .{.allocator = coral.heap.allocator},
	body_texture: ona.gfx.Texture = .default,
	render_texture: ona.gfx.Texture = .default,
	ca_effect: ona.gfx.Effect = .default,
};

const Player = struct {
	move_x: ona.act.Axis = .{.keys = .{.a, .d}},
	move_y: ona.act.Axis = .{.keys = .{.w, .s}},
};

pub fn main() !void {
	try ona.start_app(setup, .{
		.tick_rate = 60,
		.execution = .{.thread_share = 0.1},
	});
}

fn load(config: ona.Write(ona.gfx.Config), actors: ona.Write(Actors), assets: ona.Write(ona.gfx.Assets)) !void {
	config.res.width, config.res.height = .{1280, 720};
	actors.res.body_texture = try assets.res.load_texture_file(coral.files.bundle, "actor.bmp");

	actors.res.render_texture = try assets.res.load_texture(.{
		.format = .rgba8,

		.access = .{
			.render = .{
				.width = config.res.width,
				.height = config.res.height,
			},
		},
	});

	actors.res.ca_effect = try assets.res.load_effect_file(coral.files.bundle, "./ca.frag.spv");

	try actors.res.instances.push_grow(.{0, 0});
}

fn exit(actors: ona.Write(Actors)) void {
	actors.res.instances.deinit();
}

fn render(commands: ona.gfx.Commands, actors: ona.Write(Actors)) !void {
	try commands.set_effect(actors.res.ca_effect, ChromaticAberration{
		.magnitude = 15.0,
	});

	for (actors.res.instances.values) |instance| {
		try commands.draw_texture(.{
			.texture = actors.res.body_texture,

			.transform = .{
				.origin = instance,
				.xbasis = .{64, 0},
				.ybasis = .{0, 64},
			},
		});
	}
}

fn update(player: ona.Read(Player), actors: ona.Write(Actors), mapping: ona.Read(ona.act.Mapping)) !void {
	actors.res.instances.values[0] += .{
		mapping.res.axis_strength(player.res.move_x) * 10,
		mapping.res.axis_strength(player.res.move_y) * 10,
	};
}

fn setup(world: *ona.World, events: ona.App.Events) !void {
	try world.set_resource(Actors{});
	try world.set_resource(Player{});

	try world.on_event(events.load, ona.system_fn(load), .{.label = "load"});
	try world.on_event(events.update, ona.system_fn(update), .{.label = "update"});
	try world.on_event(events.exit, ona.system_fn(exit), .{.label = "exit"});
	try world.on_event(events.render, ona.system_fn(render), .{.label = "render actors"});
}