ona/src/main.zig

const coral = @import("coral");

const std = @import("std");

const ona = @import("ona");

const Actors = struct {
	instances: coral.stack.Sequential(ona.gfx.Point2D) = .{.allocator = coral.heap.allocator},
	quad_mesh_2d: ?*ona.gfx.Handle = null,
	body_texture: ?*ona.gfx.Handle = null,
	render_texture: ?*ona.gfx.Handle = null,
};

const Player = struct {
	move_x: ona.act.Axis = .{.keys = .{.a, .d}},
	move_y: ona.act.Axis = .{.keys = .{.w, .s}},
};

pub fn main() !void {
	try ona.start_app(setup, .{
		.tick_rate = 60,
		.execution = .{.thread_share = 0.1},
	});
}

fn load(display: ona.Write(ona.gfx.Display), actors: ona.Write(Actors), assets: ona.Write(ona.gfx.Assets)) !void {
	display.res.width, display.res.height = .{1280, 720};
	actors.res.body_texture = try assets.res.create_from_file(coral.files.bundle, "actor.bmp");
	actors.res.quad_mesh_2d = try assets.res.create_quad_mesh_2d(@splat(1));

	actors.res.render_texture = try assets.res.context.create(.{
		.texture = .{
			.format = .rgba8,

			.access = .{
				.render = .{
					.width = display.res.width,
					.height = display.res.height,
				},
			},
		},
	});

	try actors.res.instances.push_grow(.{0, 0});
}

fn exit(actors: ona.Write(Actors)) void {
	actors.res.instances.deinit();
}

fn render(queue: ona.gfx.Queue, actors: ona.Write(Actors), display: ona.Read(ona.gfx.Display)) !void {
	try queue.commands.append(.{.target = .{
		.texture = actors.res.render_texture.?,
		.clear_color = .{0, 0, 0, 0},
		.clear_depth = 0,
	}});

	for (actors.res.instances.values) |instance| {
		try queue.commands.append(.{.instance_2d = .{
			.mesh_2d = actors.res.quad_mesh_2d.?,
			.texture = actors.res.body_texture.?,

			.transform = .{
				.origin = instance,
				.xbasis = .{64, 0},
				.ybasis = .{0, 64},
			},
		}});
	}

	try queue.commands.append(.{.target = .{
		.clear_color = null,
		.clear_depth = null,
	}});

	try queue.commands.append(.{.instance_2d = .{
		.mesh_2d = actors.res.quad_mesh_2d.?,
		.texture = actors.res.render_texture.?,

		.transform = .{
			.origin = .{@floatFromInt(display.res.width / 2), @floatFromInt(display.res.height / 2)},
			.xbasis = .{@floatFromInt(display.res.width), 0},
			.ybasis = .{0, @floatFromInt(display.res.height)},
		},
	}});
}

fn update(player: ona.Read(Player), actors: ona.Write(Actors), mapping: ona.Read(ona.act.Mapping)) !void {
	actors.res.instances.values[0] += .{
		mapping.res.axis_strength(player.res.move_x) * 10,
		mapping.res.axis_strength(player.res.move_y) * 10,
	};
}

fn setup(world: *ona.World, events: ona.App.Events) !void {
	try world.set_resource(Actors{});
	try world.set_resource(Player{});

	try world.on_event(events.load, ona.system_fn(load), .{.label = "load"});
	try world.on_event(events.update, ona.system_fn(update), .{.label = "update"});
	try world.on_event(events.exit, ona.system_fn(exit), .{.label = "exit"});
	try world.on_event(events.render, ona.system_fn(render), .{.label = "render actors"});
}