ona/src/sys.zig

const ext = @cImport({
    @cInclude("SDL2/SDL.h");
});

const io = @import("./io.zig");
const mem = @import("./mem.zig");
const stack = @import("./stack.zig");
const std = @import("std");

///
///
///
pub const EventLoop = opaque {
    ///
    ///
    ///
    const FileSystemMessage = struct {
        next: ?*FileSystemMessage = null,
        frame: anyframe,

        request: union(enum) {
            close: struct {
                file_access: *FileAccess,
            },

            open: struct {
                mode: OpenMode,
                path: *const FileSystem.Path,
                result: OpenError!*FileAccess = error.NotFound,
            },

            read_file: struct {
                file_access: *FileAccess,
                buffer: []const u8,
                result: FileError!usize = error.Inaccessible,
            },

            seek_file: struct {
                file_access: *FileAccess,
                origin: SeekOrigin,
                offset: usize,
                result: FileError!void = error.Inaccessible,
            },

            tell_file: struct {
                file_access: *FileAccess,
                result: FileError!usize = error.Inaccessible,
            },
        },
    };

    ///
    ///
    ///
    const Implementation = struct {
        user_prefix: []const u8,
        file_system_semaphore: *ext.SDL_sem,
        file_system_thread: *ext.SDL_Thread,
        file_system_messages: ?*FileSystemMessage = null,

        fn cast(event_loop: *EventLoop) *Implementation {
            return @ptrCast(*Implementation, @alignCast(@alignOf(Implementation), event_loop));
        }
    };

    ///
    ///
    ///
    pub const OpenError = error {
        NotFound,
        BadFileSystem,
    };

    ///
    ///
    ///
    pub const OpenMode = enum {
        readonly,
        overwrite,
        append,
    };

    ///
    ///
    ///
    pub const SeekOrigin = enum {
        head,
        tail,
        current,
    };

    ///
    ///
    ///
    pub fn close(event_loop: *EventLoop, file_access: *FileAccess) void {
        var message = FileSystemMessage{
            .frame = @frame(),
            .request = .{.close = .{.file_access = file_access}},
        };

        suspend event_loop.enqueueFileSystemMessage(&message);
    }

    ///
    ///
    ///
    pub fn enqueueFileSystemMessage(event_loop: *EventLoop, message: *FileSystemMessage) void {
        const implementation = Implementation.cast(event_loop);

        if (implementation.file_system_messages) |messages| {
            messages.next = message;
        } else {
            implementation.file_system_messages = message;
        }

        // TODO: Post message to FS thread to perform task.
    }

    ///
    ///
    ///
    pub fn log(event_loop: *EventLoop, message: []const u8) void {
        // TODO: Implement.
        _ = event_loop;
        _ = message;
    }

    ///
    ///
    ///
    pub fn open(event_loop: *EventLoop, mode: OpenMode,
        path: FileSystem.Path) OpenError!*FileAccess {

        var message = FileSystemMessage{
            .frame = @frame(),

            .request = .{
                .open = .{
                    .mode = mode,
                    .path = &path,
                },
            },
        };

        suspend event_loop.enqueueFileSystemMessage(&message);

        return message.request.open.result;
    }

    ///
    ///
    ///
    fn processFileSystemMessages(data: ?*anyopaque) callconv(.C) c_int {
        const implementation = Implementation.cast(@ptrCast(*EventLoop, data orelse unreachable));

        while (implementation.file_system_messages) |messages| {
            switch (messages.request) {
                .open => |*open_request| {
                    switch (open_request.path.file_system) {
                        .data => {
                            // TODO: Implement
                            open_request.result = error.NotFound;
                        },

                        .user => {
                            var path_buffer = std.mem.zeroes([4096]u8);
                            var path = stack.Fixed(u8){.buffer = path_buffer[0 .. ]};

                            path.pushAll(implementation.user_prefix) catch {
                                open_request.result = error.BadFileSystem;

                                continue;
                            };

                            if (!open_request.path.write(path.writer())) {
                                open_request.result = error.NotFound;

                                continue;
                            }

                            if (ext.SDL_RWFromFile(&path_buffer, switch (open_request.mode) {
                                .readonly => "rb",
                                .overwrite => "wb",
                                .append => "ab",
                            })) |rw_ops| {
                                open_request.result = @ptrCast(*FileAccess, rw_ops);
                            } else {
                                open_request.result = error.NotFound;
                            }
                        },
                    }
                },

                .close => |*close_request| {
                    // Don't care if this doesn't work.
                    _ = ext.SDL_RWclose(@ptrCast(*ext.SDL_RWops, @alignCast(
                            @alignOf(ext.SDL_RWops), close_request.file_access)));
                },

                .read_file => |read_request| {
                    _ = read_request;
                },

                .seek_file => |seek_request| {
                    _ = seek_request;
                },

                .tell_file => |tell_request| {
                    _ = tell_request;
                },
            }

            resume messages.frame;

            implementation.file_system_messages = messages.next;
        }

        return 0;
    }

    ///
    ///
    ///
    pub fn readFile(event_loop: *EventLoop, file_access: *FileAccess,
        buffer: []const u8) FileError!usize {

        var message = FileSystemMessage{
            .frame = @frame(),

            .request = .{
                .read_file = .{
                    .file_access = file_access,
                    .buffer = buffer,
                },
            },
        };

        suspend event_loop.enqueueFileSystemMessage(&message);

        return message.request.read_file.result;
    }

    ///
    ///
    ///
    pub fn seekFile(event_loop: *EventLoop, file_access: *FileAccess,
        origin: SeekOrigin, offset: usize) FileError!void {

        var message = FileSystemMessage{
            .frame = @frame(),

            .request = .{
                .seek_file = .{
                    .file_access = file_access,
                    .origin = origin,
                    .offset = offset,
                },
            },
        };

        suspend event_loop.enqueueFileSystemMessage(&message);

        return message.request.seek_file.result;
    }

    ///
    ///
    ///
    pub fn tellFile(event_loop: *EventLoop, file_access: *FileAccess) FileError!usize {
        var message = FileSystemMessage{
            .frame = @frame(),
            .request = .{.tell_file = .{.file_access = file_access}},
        };

        suspend event_loop.enqueueFileSystemMessage(&message);

        return message.request.tell_file.result;
    }
};

///
///
///
pub const FileAccess = opaque {
    ///
    /// Scans the number of bytes in the file referenced by `file_access` via `event_loop`, returing
    /// its byte size or a [FileError] if it failed.
    ///
    pub fn size(file_access: *FileAccess, event_loop: *EventLoop) FileError!usize {
        // Save cursor to return to it later.
        const origin_cursor = try event_loop.tellFile(file_access);

        try event_loop.seekFile(file_access, .tail, 0);

        const ending_cursor = try event_loop.tellFile(file_access);

        // Return to original cursor.
        try event_loop.seekFile(file_access, .head, origin_cursor);

        return ending_cursor;
    }
};

///
/// With files typically being backed by a block device, they can produce a variety of errors -
/// from physical to virtual errors - these are all encapsulated by the API as general
/// [Error.Inaccessible] errors.
///
pub const FileError = error {
    Inaccessible,
};

///
///
///
pub const FileSystem = enum {
    data,
    user,

    ///
    /// Platform-agnostic mechanism for referencing files and directories on a [FileSystem]
    ///
    pub const Path = struct {
        file_system: FileSystem,
        length: u16,
        buffer: [max]u8,

        ///
        /// Returns `true` if the length of `path` is empty, otherwise `false`.
        ///
        pub fn isEmpty(path: Path) bool {
            return (path.length == 0);
        }

        ///
        /// Returns `true` if `this` is equal to `that`, otherwise `false`.
        ///
        pub fn equals(this: Path, that: Path) bool {
            return std.mem.eql(u8, this.buffer[0 .. this.length], that.buffer[0 .. that.length]);
        }

        ///
        /// The maximum possible byte-length of a [Path].
        ///
        /// Note that paths are encoded using UTF-8, meaning that a character may be bigger than one
        /// byte. Because of this, it is not safe to asume that a path may hold [max] individual
        /// characters.
        ///
        pub const max = 1000;

        ///
        ///
        ///
        pub fn write(path: Path, writer: io.Writer) bool {
            return (writer.write(path.buffer[0 .. path.length]) == path.length);
        }
    };

    ///
    /// [PathError.TooLong] occurs when creating a path that is greater than the maximum size **in
    /// bytes**.
    ///
    pub const PathError = error {
        TooLong,
    };

    ///
    /// Creates and returns a [Path] value in the file system to the location specified by the
    /// joining of the `sequences` path values.
    ///
    pub fn joinedPath(file_system: FileSystem, sequences: []const []const u8) PathError!Path {
        var path = Path{
            .file_system = file_system,
            .buffer = std.mem.zeroes([Path.max]u8),
            .length = 0,
        };

        for (sequences) |sequence| if (sequence.len != 0) {
            var components = mem.Spliterator(u8){
                .source = sequence,
                .delimiter = "/",
            };

            while (components.next()) |component| if (component.len != 0) {
                for (component) |byte| {
                    if (path.length == Path.max) return error.TooLong;

                    path.buffer[path.length] = byte;
                    path.length += 1;
                }

                if (path.length == Path.max) return error.TooLong;

                path.buffer[path.length] = '/';
                path.length += 1;
            };
        };

        return path;
    }
};

///
///
///
pub const GraphicsContext = opaque {
    ///
    ///
    ///
    pub const Event = struct {
        keys_up: Keys = std.mem.zeroes(Keys),
        keys_down: Keys = std.mem.zeroes(Keys),
        keys_held: Keys = std.mem.zeroes(Keys),

        const Keys = [256]bool;
    };

    const Implementation = struct {
        event: Event,
    };

    ///
    ///
    ///
    pub fn poll(graphics_context: *GraphicsContext) ?*const Event {
        _ = graphics_context;

        return null;
    }

    ///
    ///
    ///
    pub fn present(graphics_context: *GraphicsContext) void {
        // TODO: Implement;
        _ = graphics_context;
    }
};

///
///
///
pub fn GraphicsRunner(comptime Errors: type) type {
    return fn (*EventLoop, *GraphicsContext) Errors!void;
}

///
///
///
pub fn runGraphics(comptime Errors: anytype, run: GraphicsRunner(Errors)) Errors!void {
    if (ext.SDL_Init(ext.SDL_INIT_EVERYTHING) != 0) {
        ext.SDL_LogCritical(ext.SDL_LOG_CATEGORY_APPLICATION, "Failed to initialize SDL2 runtime");

        return error.InitFailure;
    }

    defer ext.SDL_Quit();

    const pref_path = create_pref_path: {
        const path = ext.SDL_GetPrefPath("ona", "ona") orelse {
            ext.SDL_LogCritical(ext.SDL_LOG_CATEGORY_APPLICATION, "Failed to load user path");

            return error.InitFailure;
        };

        break: create_pref_path path[0 .. std.mem.len(path)];
    };

    defer ext.SDL_free(pref_path.ptr);

    const window = create_window: {
        const pos = ext.SDL_WINDOWPOS_UNDEFINED;
        var flags = @as(u32, 0);

        break: create_window ext.SDL_CreateWindow("Ona", pos, pos, 640, 480, flags) orelse {
            ext.SDL_LogCritical(ext.SDL_LOG_CATEGORY_APPLICATION, "Failed to load SDL2 window");

            return error.InitFailure;
        };
    };

    defer ext.SDL_DestroyWindow(window);

    const renderer = create_renderer: {
        var flags = @as(u32, 0);

        break: create_renderer ext.SDL_CreateRenderer(window, -1, flags) orelse {
            ext.SDL_LogCritical(ext.SDL_LOG_CATEGORY_APPLICATION, "Failed to load SDL2 renderer");

            return error.InitFailure;
        };
    };

    defer ext.SDL_DestroyRenderer(renderer);

    var event_loop = EventLoop.Implementation{
        .file_system_semaphore = ext.SDL_CreateSemaphore(0) orelse return error.InitFailure,
        .file_system_thread = unreachable,
        .user_prefix = pref_path,
    };

    event_loop.file_system_thread = ext.SDL_CreateThread(EventLoop.processFileSystemMessages,
            "File System Worker", &event_loop) orelse return error.InitFailure;

    defer {
        ext.SDL_DestroyThread(event_loop.file_system_thread);
        ext.SDL_DestroySemaphore(event_loop.file_system_semaphore);
    }

    var graphics_context = GraphicsContext.Implementation{
        .event = .{

        },
    };

    return run(@ptrCast(*EventLoop, &event_loop), @ptrCast(*GraphicsContext, &graphics_context));
}