class_name DynamicTerrainInstance3D extends TerrainInstance3D

##
## Blank sample value.
##
const BLANK := Color(0.0, 0.0, 0.0, 0.0)

var _editable_image: Image

var _editable_texture: ImageTexture

func _get_brush_area(point: Vector2i, mask_size: Vector2i, mask_scale: float) -> Rect2i:
	# Convert worldspace point to image-space coordinates for mask.
	var scaled_mask_size := Vector2i(mask_size * mask_scale)

	return Rect2i((point + Vector2i(get_size() * 0.5)) - Vector2i(scaled_mask_size * 0.5), scaled_mask_size)

func _init() -> void:
	super._init()

	_editable_image = Image.create(1, 1, false, Image.FORMAT_RGBAF)
	_editable_texture = ImageTexture.create_from_image(_editable_image)

	super.resize(Vector2i.ONE)

##
## Clears the terrain map to the value of [code]clear_elevation[/code].
##
func clear(clear_elevation: float) -> void:
	_editable_image.fill(Color(0.0, 0.0, 0.0, clampf(clear_elevation, 0.0, 1.0)))
	_editable_texture.update(_editable_image)

##
##
##
func oscillate(point: Vector2i, level: float,
	mask: Image, mask_scale: float, intensity: float, delta: float) -> void:

	var mask_size := mask.get_size()
	var brush_source := _get_brush_area(point, mask_size, mask_scale)

	if brush_source.has_area():
		var brush_target := Rect2i(Vector2i.ZERO, get_size()).intersection(brush_source)

		if brush_target.has_area():
			var mask_ratio := mask_size / brush_source.size
			var offset := brush_target.position - brush_source.position

			for y in brush_target.size.y:
				var mask_y := int((offset.y + y) * mask_ratio.y)

				for x in brush_target.size.x:
					var coord := brush_target.position + Vector2i(x, y)
					var pixel := _editable_image.get_pixelv(coord)

					_editable_image.set_pixelv(coord, Color(pixel.r, pixel.g, pixel.b,
						lerpf(pixel.a, level, intensity * delta *\
							mask.get_pixel(int((offset.x + x) * mask_ratio.x), mask_y).a)).clamp())

		_editable_texture.update(_editable_image)

##
##
##
func paint(point: Vector2i, color: Color,
	mask: Image, mask_scale: float, intensity: float, delta: float) -> void:

	var mask_size := mask.get_size()
	var brush_source := _get_brush_area(point, mask_size, mask_scale)

	if brush_source.has_area():
		var brush_target := Rect2i(Vector2i.ZERO, get_size()).intersection(brush_source)

		if brush_target.has_area():
			var mask_ratio := mask_size / brush_source.size
			var offset := brush_target.position - brush_source.position

			for y in brush_target.size.y:
				var mask_y := int((offset.y + y) * mask_ratio.y)

				for x in brush_target.size.x:
					var coord := brush_target.position + Vector2i(x, y)
					var pixel := _editable_image.get_pixelv(coord)

					var mask_intensity_delta := intensity * delta *\
						mask.get_pixel(int((offset.x + x) * mask_ratio.x), mask_y).a

					_editable_image.set_pixelv(coord, Color(
						lerpf(pixel.r, color.r, mask_intensity_delta),
							lerpf(pixel.g, color.g, mask_intensity_delta),
								lerpf(pixel.b, color.b, mask_intensity_delta), pixel.a).clamp())

		_editable_texture.update(_editable_image)

##
##
##
func resize(size: Vector2i) -> void:
	super.resize(size)

	var actual_size := get_size()

	_editable_image.resize(actual_size.x, actual_size.y)

	_editable_texture = ImageTexture.create_from_image(_editable_image)

	update_terrain(_editable_texture)

##
## Samples the color value in the editable terrain at the worldspace [code]point[/code], returning
## its respective [Color] value.
##
## For sample coordinates outside of the terrain map worldspace, [code]BLANK[/code] is returned
## instead.
##
func sample(point: Vector2i) -> Color:
	var size := get_size()
	var image_point := point + Vector2i(size * 0.5)

	if Rect2i(Vector2i.ZERO, size).has_point(image_point):
		return _editable_image.get_pixelv(image_point)

	return BLANK