const gfx = @import("gfx");

const ona = @import("ona");

const std = @import("std");

const CRT = extern struct {
	width: f32,
	height: f32,
	time: f32,
	padding: [4]u8 = undefined,
};

const Effects = struct {
	render_texture: gfx.Texture = .default,
	crt_effect: gfx.Effect = .default,
};

fn load(display: ona.Write(gfx.Display), effects: ona.Write(Effects), assets: ona.Write(gfx.Assets)) !void {
	display.state.width, display.state.height = .{1280, 720};

	effects.state.render_texture = try assets.state.load_texture(.{
		.format = .rgba8,

		.access = .{
			.render = .{
				.width = display.state.width,
				.height = display.state.height,
			},
		},
	});

	effects.state.crt_effect = try assets.state.load_effect_file(ona.files.bundle, "./crt.frag.spv");
}

pub const main = ona.App.setup.
	with_module(gfx).
	with_state(Effects{}).
	with_system(.load, ona.system_fn(load), .{.label = "load effects"}).
	with_system(.render, ona.system_fn(render), .{.label = "render effects"}).build();

fn render(commands: gfx.Commands, effects: ona.Write(Effects), app: ona.Read(ona.App), display: ona.Write(gfx.Display)) !void {
	try commands.set_target(.{
		.texture = effects.state.render_texture,
		.clear_color = gfx.colors.black,
		.clear_depth = 0,
		.clear_stencil = 0,
	});

	const display_width: f32 = @floatFromInt(display.state.width);
	const display_height: f32 = @floatFromInt(display.state.height);

	const display_transform = gfx.Transform2D{
		.origin = .{display_width / 2, display_height / 2},
		.xbasis = .{display_width, 0},
		.ybasis = .{0, display_height},
	};

	try commands.draw_texture(.{
		.texture = .default,
		.transform = display_transform,
	});

	try commands.set_effect(.{
		.effect = effects.state.crt_effect,

		.properties = std.mem.asBytes(&CRT{
			.width = display_width,
			.height = display_height,
			.time = @floatCast(app.state.elapsed_time),
		}),
	});

	try commands.set_target(.{
		.texture = null,
		.clear_color = null,
		.clear_depth = null,
		.clear_stencil = null,
	});

	try commands.draw_texture(.{
		.texture = effects.state.render_texture,
		.transform = display_transform,
	});
}