const coral = @import("coral");

const std = @import("std");

const ona = @import("ona");

const Actors = struct {
	instances: coral.stack.Sequential(@Vector(2, f32)) = .{.allocator = coral.heap.allocator},
	body_texture: ona.gfx.Texture = .default,
	render_texture: ona.gfx.Texture = .default,
};

const Player = struct {
	move_x: ona.act.Axis = .{.keys = .{.a, .d}},
	move_y: ona.act.Axis = .{.keys = .{.w, .s}},
};

pub fn main() !void {
	try ona.start_app(setup, .{
		.tick_rate = 60,
		.execution = .{.thread_share = 0.1},
	});
}

fn load(config: ona.Write(ona.gfx.Config), actors: ona.Write(Actors), assets: ona.Write(ona.gfx.Assets)) !void {
	config.res.width, config.res.height = .{1280, 720};
	actors.res.body_texture = try assets.res.load_texture_file(coral.files.bundle, "actor.bmp");

	actors.res.render_texture = try assets.res.load_texture(.{
		.format = .rgba8,

		.access = .{
			.render = .{
				.width = config.res.width,
				.height = config.res.height,
			},
		},
	});

	try actors.res.instances.push_grow(.{0, 0});
}

fn exit(actors: ona.Write(Actors)) void {
	actors.res.instances.deinit();
}

fn render(commands: ona.gfx.Commands, actors: ona.Write(Actors), config: ona.Read(ona.gfx.Config)) !void {
	try commands.set_target(.{
		.texture = actors.res.render_texture,
		.clear_color = .{0, 0, 0, 0},
		.clear_depth = 0,
		.clear_stencil = 0,
	});

	for (actors.res.instances.values) |instance| {
		try commands.draw_texture(.{
			.texture = actors.res.body_texture,

			.transform = .{
				.origin = instance,
				.xbasis = .{64, 0},
				.ybasis = .{0, 64},
			},
		});
	}

	try commands.set_target(.{
		.clear_color = null,
		.clear_depth = null,
		.clear_stencil = null,
	});

	try commands.draw_texture(.{
		.texture = actors.res.render_texture,

		.transform = .{
			.origin = .{@floatFromInt(config.res.width / 2), @floatFromInt(config.res.height / 2)},
			.xbasis = .{@floatFromInt(config.res.width), 0},
			.ybasis = .{0, @floatFromInt(config.res.height)},
		},
	});
}

fn update(player: ona.Read(Player), actors: ona.Write(Actors), mapping: ona.Read(ona.act.Mapping)) !void {
	actors.res.instances.values[0] += .{
		mapping.res.axis_strength(player.res.move_x) * 10,
		mapping.res.axis_strength(player.res.move_y) * 10,
	};
}

fn setup(world: *ona.World, events: ona.App.Events) !void {
	try world.set_resource(Actors{});
	try world.set_resource(Player{});

	try world.on_event(events.load, ona.system_fn(load), .{.label = "load"});
	try world.on_event(events.update, ona.system_fn(update), .{.label = "update"});
	try world.on_event(events.exit, ona.system_fn(exit), .{.label = "exit"});
	try world.on_event(events.render, ona.system_fn(render), .{.label = "render actors"});
}